Sử dụng Try... Catch..., Finally!

Private Sub btnSimpleTryCatch_Click(ByVal sender As System.Object, _
    ByVal e As System.EventArgs) Handles btnSimpleTryCatch.Click
        Try
            ' Một vài dòng code ở đây
            ' Lỗi xảy ra!
            Throw New System.Exception("Một lỗi không mong muốn đã xảy ra")
            'Một số mã thêm ở đây ... Chúng sẽ không được thực thi nếu ngoại lệ xảy ra.
        Catch ex As Exception
            ' Xử lý các trường hợp ngoại lệ.
            MessageBox.Show(ex.Message, Me.Text, _
        MessageBoxButtons.OK, MessageBoxIcon.Error)
        End Try
    End Sub

Private Sub btnSimpleTryCatchFinally_Click(ByVal sender As System.Object, _
    ByVal e As System.EventArgs) Handles btnSimpleTryCatchFinally.Click
        ' Con trỏ chuyển sang chế độ chờ.
        Me.Cursor = Cursors.WaitCursor
        Try
            ' Một số mã ở đây ...
            ' Thời gian chờ đợi!
            Threading.Thread.Sleep(5000)
            ' Lỗi xảy ra!
            Throw New System.Exception("Xảy ra lỗi không mong muốn.")
            ' Một số mã thêm ở đây ...
        Catch ex As Exception
            ' Xử lý các trường hợp ngoại lệ.
            MessageBox.Show(ex.Message, Me.Text, MessageBoxButtons.OK, MessageBoxIcon.Error)
        Finally
            ' Hãy chắc chắn rằng con trỏ được thiết lập trở lại mặc định!
            Me.Cursor = Cursors.Default
        End Try
    End Sub

Private Sub btnMultipleCatches_Click(ByVal sender As System.Object, _
    ByVal e As System.EventArgs) Handles btnMultipleCatches.Click
        Try
            ' Một số mã ở đây ...
            ' Hãy chỉ ra rằng chúng ta đang cố mở một tập tin ở đây.
            ' Lỗi xảy ra!
            Dim rand As New Random
            If rand.Next(2) = 1 Then
                Throw New IO.FileNotFoundException_
        ("Tập tin bạn đang cố gắng mở không được tìm thấy. ")
            Else
                Throw New System.Exception("Có lỗi xảy ra không rõ.")
            End If
            ' Một số mã thêm ở đây ...
        Catch dirEx As IO.DirectoryNotFoundException
            ' xử lý DirectoryNotFoundException ở đây.
            MessageBox.Show(dirEx.Message, "Thư mục không tìm thấy", _
        MessageBoxButtons.OK, MessageBoxIcon.Error)
        Catch fileEx As IO.FileNotFoundException
            ' Xử lý FileNotFoundException ở đây.
            MessageBox.Show(fileEx.Message, "File not found", _
        MessageBoxButtons.OK, MessageBoxIcon.Error)
        Catch ioEx As IO.IOException
            ' Xử lý ngoại lệ IO ở đây.
            MessageBox.Show(ioEx.Message, "IO exception", _
        MessageBoxButtons.OK, MessageBoxIcon.Error)
        Catch ex As Exception
            ' Xử lý bất kỳ ngoại lệ IO khác ở đây.
            MessageBox.Show(ex.Message, "Ngoại lệ Không biết", _
        MessageBoxButtons.OK, MessageBoxIcon.Error)
        End Try
    End Sub

Private Sub btnExceptionsFromDeeperMethods_Click(ByVal sender As System.Object, _
    ByVal e As System.EventArgs) Handles btnExceptionsFromDeeperMethods.Click
        Try
            Dim mm As New ManyMethods
            ' This method goes into three other methods!
            mm.GoIntoDeeperMethods()
        Catch ex As Exception
            MessageBox.Show(ex.Message & Environment.NewLine & _
                            "The method which threw me was: " & ex.TargetSite.Name, _
                            Me.Text, MessageBoxButtons.OK, MessageBoxIcon.Error)
        End Try
    End Sub

    Public Sub GoIntoDeeperMethods()
        B() ' Goes into B, which goes into C, which goes into ExceptionMethod,
            ' which throws an error.
        MessageBox.Show("You will never see me!", "Some deeper method", _
        MessageBoxButtons.OK, MessageBoxIcon.Information)
        AA() ' Will never be executed.
        AB() ' Will never be executed.
    End Sub

    ' Method B, C, AA and AB show MessageBoxes,
         ' but only after eventually calling the ExceptionMethod.
    ' The MessageBoxes will therefore never be prompted.

    Private Sub ExceptionMethod()
        ' Some code here...
        ' Oops! An error occurs!
        Throw New System.Exception("I am coming from way down here!") ' This returns
        ' to the first Catch block, in the case in the button Event Handler.
        ' Some code here...
    End Sub

Private Sub btnFinallyInDeeperMethods_Click(ByVal sender As System.Object, _
    ByVal e As System.EventArgs) Handles btnFinallyInDeeperMethods.Click
        Try
            Dim mm As New ManyMethods
            ' This method goes into four other methods!
            mm.GoIntoDeeperMethodsWithFinally()
        Catch ex As Exception
            MessageBox.Show(ex.Message & Environment.NewLine & _
                            "The method which threw me was: " & ex.TargetSite.Name, _
                            Me.Text, MessageBoxButtons.OK, MessageBoxIcon.Error)
        End Try
    End Sub

    Public Sub GoIntoDeeperMethodsWithFinally()
        Try
            ' This will eventually throw an exception.
            GoIntoDeeperMethods()
        Finally
            ' This code will ALWAYS be executed.
            MessageBox.Show("You will always see me!", _
        "Finally", MessageBoxButtons.OK, MessageBoxIcon.Information)
        End Try
    End Sub

Private Sub btnHandlingAnExceptionMultipleTimes_Click_
    (ByVal sender As System.Object, ByVal e As System.EventArgs) _
    Handles btnHandlingAnExceptionMultipleTimes.Click
        Try
            Dim mm As New ManyMethods
            ' This method goes into four other methods!
            mm.GoIntoDeeperMethodsWithCatch()
        Catch ex As Exception
            MessageBox.Show(ex.Message & Environment.NewLine & _
                            "The method which threw me was: " & _
             ex.TargetSite.Name & Environment.NewLine & _
                            "The method which initially threw me was: _
             " & ex.InnerException.TargetSite.Name, _
                            Me.Text, MessageBoxButtons.OK, MessageBoxIcon.Error)
        End Try
    End Sub

    Public Sub GoIntoDeeperMethodsWithCatch()
        Try
            ' This will eventually throw an exception.
            GoIntoDeeperMethods()
        Catch ex As Exception
            MessageBox.Show("Do some specific error handling here...", _
        "Some deeper method", MessageBoxButtons.OK, MessageBoxIcon.Information)
            ' Rethrow the Exception to the form so the form can handle the user interface.
            Dim newEx As New System.Exception("I am rethrown!", ex)
            Throw newEx
        End Try
    End Sub

Private Sub btnNestedTryCatch_Click(ByVal sender As System.Object, _
    ByVal e As System.EventArgs) Handles btnNestedTryCatch.Click
        Try
            ' Some code here...
            Try
                ' Some more code here...
                Dim table As New DataTable
                Try
                    ' Some more code here...
                    ' Oops! An error occurs!
                    Throw New System.Exception("I come from the third nested try.")
                    ' No Catch here, only a finally.
                Finally
                    ' This code will always execute.
                    table.Dispose()
                End Try
            Catch ex As Exception
                MessageBox.Show(ex.Message & Environment.NewLine & _
        " I was handled in the second Try... Catch... block.", _
                                Me.Text, MessageBoxButtons.OK, MessageBoxIcon.Error)
            End Try
        Catch ex As Exception
            MessageBox.Show(ex.Message & Environment.NewLine & _
        " I was handled in the first Try... Catch... block.", _
                            Me.Text, MessageBoxButtons.OK, MessageBoxIcon.Error)
        End Try
    End Sub

Private Sub btnUsingEndUsing_Click(ByVal sender As System.Object, _
    ByVal e As System.EventArgs) Handles btnUsingEndUsing.Click
        Dim table1 As New DataTable
        Try
            ' Some code here...
        Finally
            table1.Dispose()
        End Try

        ' The above code actually does the same as this code!
        ' The Using... End Using block can be used with any object that
        ' implements IDisposable and makes sure that your object is disposed
        ' of, no matter what happens.
        Using table2 As New DataTable
            ' Some code here...
        End Using

        MessageBox.Show("This button does not actually do something." _
    & Environment.NewLine & "Check the source code :)", _
                        Me.Text, MessageBoxButtons.OK, MessageBoxIcon.Error)
    End Sub

Private Sub btnToSumItUp_Click(ByVal sender As System.Object, _
    ByVal e As System.EventArgs) Handles btnToSumItUp.Click
        Me.Cursor = Cursors.WaitCursor
        Try
            DoSomeSqlStuff()
            ' This is an alternative block of code that does the same
            ' as DoSomeSqlStuff, but looks quite differently.
            ' AlternativeDoSomeSqlStuff()
        Catch sqlEx As SqlClient.SqlException
            MessageBox.Show(sqlEx.Message, "SQL Exception", _
        MessageBoxButtons.OK, MessageBoxIcon.Error)
        Catch ex As Exception
            MessageBox.Show(ex.Message, "Unknown exception", _
        MessageBoxButtons.OK, MessageBoxIcon.Error)
        Finally
            ' Make sure the cursor is set back to default!
            Me.Cursor = Cursors.Default
        End Try
    End Sub

    Private Sub DoSomeSqlStuff()
        Using connection As New SqlClient.SqlConnection_
    ("Data Source=SomeServer;Initial Catalog=SomeDB;Integrated Security=True")
            Using cmd As New SqlClient.SqlCommand_
        ("SELECT * FROM SomeTable", connection)
                connection.Open()
                Try
                    Using reader As SqlClient.SqlDataReader = cmd.ExecuteReader
                        While reader.Read
                            ' Do something... This will never happen :)
                        End While
                    End Using ' SqlReader is disposed.
                Finally
                    ' Always close the connection!
                    connection.Close()
                End Try
            End Using ' SqlCommand is disposed.
        End Using ' SqlConnection is disposed.
    End Sub

Private Sub AlternativeDoSomeSqlStuff()
        Dim connection As New SqlClient.SqlConnection_
    ("Data Source=SomeServer;Initial Catalog=SomeDB;Integrated Security=True")
        Dim cmd As New SqlClient.SqlCommand("SELECT * FROM SomeTable", connection)
        Try
            connection.Open()
            Using reader As SqlClient.SqlDataReader = cmd.ExecuteReader
                While reader.Read
                    ' Do something... This will never happen :)
                End While
            End Using ' SqlReader is disposed.
        Finally
            connection.Close()
            connection.Dispose()
            cmd.Dispose()
        End Try
    End Sub